NOTICE TEXTE n° 1 (1.28 Ko) 
1 'Kukulcan 2016
2 'Incrustation Couleur CPC - ecrire
10 OPENOUT "D":MEMORY &8800:CLOSEOUT
20 GOSUB 280
30 MODE 1:BORDER 0:INK 0,0:INK 1,26:PEN 1
40 INPUT "Nom du fichier (.SCR)",file$
50 IF file$="" THEN a$="*.SCR":|DIR,@a$:GOTO 40
60 CLS
70 LOAD file$+".PAL",&8809
80 LOAD file$+".SCR",&C000
90 REM *** ECRIRE ASM DANS IMAGE ***
100 GOSUB 370
110 REM *** MODE ***
120 a=PEEK(&8809)
130 POKE &FFD1,a
140 REM *** BORDER ***
150 a=PEEK(&880C)
160 POKE &FFD6,couleur(a)
170 POKE &FFD7,couleur(a)
180 REM *** LES 16 COULEURS ***
190 FOR i=0 TO 15
200 a=PEEK(&880C+(i*12))
210 POKE &FFF0+i,couleur(a)
220 NEXT
230 CALL &FFD0:'Changer Mode, Border, Couleurs
240 SAVE file$+".ECR",B,&C000,&4000
250 LOCATE 1,1:PRINT "SAUVEGARDE FINIE"
260 PRINT CHR$(7):CALL &BB06:GOTO 30
270 END
280 '*** ConvImgCpc - DECODAGE DES ENCRES DU PAL POUR CPC ***
290 DIM couleur(128)
300 RESTORE 360
310 FOR i=0 TO 26
320 READ a
330 couleur(a)=i
340 NEXT
350 RETURN
360 DATA 84,68,85,92,88,93,76,69,77,86,70,87,94,64,95,78,71,79,82,66,83,90,89,91,74,67,75
370 '*** Routine ASM ***
380 RESTORE 400
390 FOR i=&FFD0 TO &FFEE:READ a$:POKE i,VAL("&"+a$):NEXT:RETURN
400 DATA 3E,00,CD,1C,BD
410 DATA 01,00,00,CD,38,BC
420 DATA 21,F0,FF,AF,F5,E5,46,48
430 DATA CD,32,BC,E1,23,F1,3C,FE,10,20,F1,C9
NOTICE TEXTE n° 3 (267 o) 
1 'Kukulcan 2016
2 'Incrustation Couleur CPC - lecture
10 MODE 1:BORDER 0:INK 0,0:INK 1,26:PEN 1
20 INPUT "Nom du fichier (.ECR)",file$
30 IF file$="" THEN a$="*.ECR":|DIR,@a$:GOTO 20
40 LOAD file$+".ECR",&C000
50 CALL &FFD0
60 PRINT CHR$(7):CALL &BB06:GOTO 10